first commit

lib/Arduino_MFRC522v2-master/examples/Hack/ChangeUID/ChangeUID.ino

@@ -0,0 +1,88 @@
+/*
+ * --------------------------------------------------------------------------------------------------------------------
+ * Example to change UID of changeable MIFARE card.
+ * --------------------------------------------------------------------------------------------------------------------
+ * This is a MFRC522 library example; for further details and other examples see: https://github.com/OSSLibraries/Arduino_MFRC522v2
+ * 
+ * This sample shows how to set the UID on a UID changeable MIFARE card.
+ * 
+ * @author Tom Clement
+ * @license Released into the public domain.
+ *
+ * Typical pin layout used:
+ * -----------------------------------------------------------------------------------------
+ *             MFRC522      Arduino       Arduino   Arduino    Arduino          Arduino
+ *             Reader/PCD   Uno/101       Mega      Nano v3    Leonardo/Micro   Pro Micro
+ * Signal      Pin          Pin           Pin       Pin        Pin              Pin
+ * -----------------------------------------------------------------------------------------
+ * SPI SS      SDA(SS)      10            53        D10        10               10
+ * SPI MOSI    MOSI         11 / ICSP-4   51        D11        ICSP-4           16
+ * SPI MISO    MISO         12 / ICSP-1   50        D12        ICSP-1           14
+ * SPI SCK     SCK          13 / ICSP-3   52        D13        ICSP-3           15
+ *
+ * Not found? For more see: https://github.com/OSSLibraries/Arduino_MFRC522v2#pin-layout
+ */
+
+#include <MFRC522v2.h>
+#include <MFRC522DriverSPI.h>
+//#include <MFRC522DriverI2C.h>
+#include <MFRC522DriverPinSimple.h>
+#include <MFRC522Debug.h>
+#include <MFRC522Hack.h>
+
+MFRC522DriverPinSimple ss_pin(10); // Configurable, see typical pin layout above.
+
+MFRC522DriverSPI driver(ss_pin);
+//MFRC522DriverI2C driver();
+MFRC522 mfrc522(driver);  // Create MFRC522 instance.
+MFRC522Hack mfrc522Hack(mfrc522, true);  // Create MFRC522Hack instance.
+
+/* Set your new UID here! */
+constexpr uint8_t newUid[] = {0xDE, 0xAD, 0xBE, 0xEF};
+
+MFRC522::MIFARE_Key key;
+
+void setup() {
+  Serial.begin(115200);  // Initialize serial communications with the PC for debugging.
+  while (!Serial);     // Do nothing if no serial port is opened (added for Arduinos based on ATMEGA32U4).
+  mfrc522.PCD_Init();  // Init MFRC522 board.
+  Serial.println(F("Warning: this example overwrites the UID of your UID changeable card, use with care!"));
+  Serial.println(F("This example only works with MIFARE Classic cards."));
+  
+  // Prepare key - all keys are set to FFFFFFFFFFFFh at chip delivery from the factory.
+  for (byte i = 0; i < 6; i++) {
+    key.keyByte[i] = 0xFF;
+  }
+}
+
+void loop() {
+  // Reset the loop if no new card present on the sensor/reader. This saves the entire process when idle. And if present, select one.
+  if ( !mfrc522.PICC_IsNewCardPresent() || !mfrc522.PICC_ReadCardSerial() ) {
+    delay(50);
+    return;
+  }
+  
+  // Now a card is selected. The UID and SAK is in mfrc522.uid.
+  
+  // Dump UID.
+  Serial.print(F("Card UID:"));
+  MFRC522Debug::PrintSelectedUID(mfrc522, Serial);
+  Serial.println();
+  
+  // Set new UID.
+  if ( mfrc522Hack.MIFARE_SetUid(newUid, (byte)4, key, true) ) {
+    Serial.println(F("Wrote new UID to card."));
+  }
+  
+  // Halt PICC and re-select it so DumpToSerial doesn't get confused.
+  mfrc522.PICC_HaltA();
+  if ( !mfrc522.PICC_IsNewCardPresent() || !mfrc522.PICC_ReadCardSerial() ) {
+    return;
+  }
+  
+  // Dump the new memory contents.
+  Serial.println(F("New UID and contents:"));
+  MFRC522Debug::PICC_DumpToSerial(mfrc522, Serial, &(mfrc522.uid));
+  
+  delay(2000);
+}